home *** CD-ROM | disk | FTP | other *** search
/ Ahoy 1984 January to June / Ahoy_Magazine_84-Jan-Jun_1984_Double_L.d64 / lower case (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  2KB  |  53 lines
  1. 10 rem--ahoy--april issue--lower case---prog page 53
  2. 100 rem *** routine for printing lower case descenders ***
  3. 110 rem *** using the commodore 1515 or 1525 printers  ***
  4. 120 rem           *** by morton kevelson ***
  5. 130 rem           ***   september 1983   ***
  6. 140 print chr$(14):rem set keyboard to upper/lower case mode
  7. 150 print chr$(8):rem disable shift/commodore key
  8. 160 printchr$(147)chr$(17)chr$(17)"              reading data "
  9. 170 dim lc$(5),ds$(5)
  10. 180 data8,184,196,196,196,248,128,15,17:rem ** upper half of 'g' **
  11. 190 data8,128,128,132,253,128,128,15,17:rem ** upper half of 'j' **
  12. 200 data8,252,196,196,184,128,128,15,17:rem ** upper half of 'p' **
  13. 210 data8,184,196,196,252,128,128,15,17:rem ** upper half of 'q' **
  14. 220 data8,188,192,192,252,128,128,15,17:rem ** upper half of 'y' **
  15. 230 data8,128,132,132,132,131,128,15,17:rem ** descender for 'g' **
  16. 240 data8,128,130,132,131,128,128,15,17:rem ** descender for 'j' **
  17. 250 data8,135,128,128,128,128,128,15,17:rem ** descender for 'p' **
  18. 260 data8,128,128,128,135,128,128,15,17:rem ** descender for 'q' **
  19. 270 data8,132,132,132,131,128,128,15,17:rem ** descender for 'y' **
  20. 280 fori=1to5:forj=1to9
  21. 300 readlc
  22. 310 lc$(i)=lc$(i)+chr$(lc)
  23. 330 nextj:nexti
  24. 340 fori=1to5:forj=1to9
  25. 360 readds
  26. 370 ds$(i)=ds$(i)+chr$(ds)
  27. 390 nextj:nexti
  28. 400 p5$="":rem temporary string for main text.
  29. 410 su$="":rem temporary string for descender graphics.
  30. 420 print"type a sentence"
  31. 430 input a$
  32. 440 l=len(a$):g=0
  33. 450 fori=1 to l
  34. 460 a5$=mid$(a$,i,1)
  35. 470 ifa5$=chr$(71)theng=1:rem ** check for lower case 'g' **
  36. 480 ifa5$=chr$(74)theng=2:rem ** check for lower case 'j' **
  37. 490 ifa5$=chr$(80)theng=3:rem ** check for lower case 'p' **
  38. 500 ifa5$=chr$(81)theng=4:rem ** check for lower case 'q' **
  39. 510 ifa5$=chr$(89)theng=5:rem ** check for lower case 'y' **
  40. 520 ifg=0goto550
  41. 530 p5$=p5$+lc$(g):rem use custom graphics for g,j,p,q,y.
  42. 540 su$=su$+ds$(g):goto560:rem custom graphics for descender line.
  43. 550 p5$=p5$+a5$:su$=su$+" "
  44. 560 g=0:nexti
  45. 570 open4,4
  46. 580 print#4,chr$(17)p5$chr$(8)
  47. 590 print#4,chr$(15)chr$(17)su$chr$(8)
  48. 600 print#4,chr$(15):close4
  49. 610 print"again ?"
  50. 620 get g$:if g$="" goto 620
  51. 630 if g$="y"goto400
  52. 640 print chr$(9)chr$(142):rem restore upper case mode. enable shift comm. key
  53.